把文件读取到字节型数组、把字节型数组内容写入文件

把文件读取到字节类型数组
读取的文本文件的内容以文字列形式取得的方法，请参考这里。在这里介绍把文件的内容读取到字节类型数组的方法。

下面的代码是使用FileStream类的Read方法，一次性读取所有文件内容方法的例子。

[VB.NET]

'读取文件的名称
Dim fileName As String = "C:\test.txt"
'打开文件
Dim fs As New System.IO.FileStream(fileName, _
System.IO.FileMode.Open, _
System.IO.FileAccess.Read)
'生成读取文件用的字节类型数组
Dim bs(fs.Length - 1) As Byte
'读取文件的所有内容
fs.Read(bs, 0, bs.Length)
'关闭
fs.Close()

把字节类型数组内容写入文件
接下面介绍把字节类型数组的内容写入文件的方法。关于把文字列写的文本文件的方法，请参考这里。

下面的代码是使用FileStream类的Write方法，把字节类型数组（“bs”）写入文件的例子。

[VB.NET]

'写入文件用的字节类型数组“bs”
'Dim bs() As Byte

'写入文件的名称
Dim fileName As String = "C:\test.txt"
'打开文件
Dim fs As New System.IO.FileStream(fileName, _
System.IO.FileMode.Create, _
System.IO.FileAccess.Write)
'写入数组的所有内容
fs.Write(bs, 0, bs.Length)
'关闭
fs.Close()

补充：在读取、写入文件时，如果文件内容过多可能会产生影响，所以最好是以量少多次的读取、写入为好。

上面例子中FileStream的第2个参数设定为「FileMode.Create」，这样当文件不存在时会生成文件，如果存在时就会覆盖。

下面是关于FileMode枚举成员的说明。

FileMode成员名称说明
Append 打开现有文件并查找到文件尾，或创建新文件。
Create 指定操作系统应创建新文件。如果文件已存在，它将被改写。
CreateNew 指定操作系统应创建新文件。如果文件已存在，则将引发IOException。
Open 指定操作系统应打开现有文件。如果该文件不存在，则引发System.IO.FileNotFoundException。
OpenOrCreate 指定操作系统应打开文件（如果文件存在）；如果该文件不存在，应创建新文件。
Truncate 指定操作系统应打开现有文件。文件一旦打开，就将被截断为零字节大小。

非同步读取、写入文件
以上所介绍的方法都是同步读取、写入文件的方法，但如果处理内容过多的文件时，应用程序可能会处于短暂的假死现象。为了防止这种现象的发生，可以使用非同步方法进行处理。文件读取可以使用BeginRead和EndRead方法；文件写入时可以使用BeginWrite和EndWrite方法。

下面的代码是非同步读取文件的例子。

[VB.NET]

Private readBytes As Byte() = Nothing

'Button1的Click事件处理器
Private Sub Button1_Click(ByVal sender As Object, _
     ByVal e As System.EventArgs) Handles Button1.Click
     readBytes = New Byte(1023) {}

     '读取文件的名称
     Dim fileName As String = "C:\file.txt"
     '打开文件
     Dim fs As New System.IO.FileStream(fileName, _
         System.IO.FileMode.Open, _
         System.IO.FileAccess.Read, _
         System.IO.FileShare.Read, _
         &H1000, _
         True)
     '非同步读取开始
     fs.BeginRead(readBytes, 0, readBytes.Length, _
         New AsyncCallback(AddressOf ReadBytesCallback), fs)
End Sub

Private Sub ReadBytesCallback(ByVal ar As IAsyncResult)
     '取得FileStream
     Dim fs As System.IO.FileStream = _
         CType(ar.AsyncState, System.IO.FileStream)
     '取得读取的大小
     Dim readSize As Integer = fs.EndRead(ar)

     If readSize > 0 Then
         fs.BeginRead(readBytes, 0, readBytes.Length, _
             New AsyncCallback(AddressOf ReadBytesCallback), fs)
     Else
         '读取所有内容后结束
         fs.Close()
     End If
End Sub

.NET Framework 2.0版本开始，不使用流进行读取
从.NET Framework 2.0版本开始，使用File.ReadAllBytes方法可以把文件的内容读取到Byte数组中。下面的代码就是读取的例子。

[VB.NET]

'读取文件的名称
Dim fileName As String = "C:\text.txt"

'fileName的内容读取到Byte数组
Dim bs As Byte() = System.IO.File.ReadAllBytes(fileName)

在VB.NET中My.Computer.FileSystem.ReadAllBytes方法同样可以实现。而且使用My.Computer.FileSystem.WriteAllBytes方法，可以把写入Byte数组。

[本日志由 tiancao1001 于 2010-12-19 07:07 PM 编辑]

分享到： QQ空间新浪微博腾讯微博微信更多

暂时没有评论

发表评论 - 不要忘了输入验证码哦！

作者：

用户：密码：注册？验证：